**/PROG RSR0001**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: ;

2: CALL MAIN\_PROGRAM\_M3 ;

3: ;

4: ;

5: ;

/POS

/END

//

**/PROG MAIN\_PROGRAM\_M3**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: RUN FENCE\_OPEN ;

2: ;

3: UFRAME\_NUM=0 ;

4: UTOOL\_NUM=1 ;

5: OVERRIDE=80% ;

6: ;

7: LBL[1] ;

8: R[58]=0 ;

9: R[59]=0 ;

10: ;

11: R[56]=60 ;

12: LBL[2] ;

13: R[R[56]]=0 ;

14: R[56]=R[56]+1 ;

15: IF R[56]<=70,JMP LBL[2] ;

16: ;

17: R[56]=60 ;

18: R[57]=60 ;

19: ;

20: DO[106]=ON ;

21: LINE[1] ON ;

22: LINE[2] ON ;

23: ;

24: RUN MAIN\_SUBPRG ;

25: ;

26: LBL[10] ;

27:L PR[19] 750mm/sec CNT25 ;

28: ;

29: WAIT R[R[57]]<>0 ;

30: SETTRIG LNSCH[1] R[R[57]] ;

31: SETTRIG LNSCH[2] R[52] ;

32: ;

33: SELBOUND LNSCH[1] BOUND[1] ;

34: SELBOUND LNSCH[2] BOUND[1] ;

35: ;

36: CALL MAIN\_PICK ;

37:L PR[19] 1250mm/sec CNT50 ;

38: CALL MAIN\_PLACE ;

39: ;

40: ;

41: R[57]=R[57]+1 ;

42: IF R[57]<=70,JMP LBL[15] ;

43: R[57]=60 ;

44: ;

45: LBL[15] ;

46: ;

47: JMP LBL[10] ;

48: ;

/POS

/END

//

**/PROG FENCE\_OPEN**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: ;

2: LBL[1] ;

3: ;

4: IF DI[105]=ON,JMP LBL[2] ;

5: JMP LBL[1] ;

6: ;

7: LBL[2] ;

8: UALM[10] ;

9: ;

/POS

/END

//

**/PROG MAIN\_SUBPRG**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: LBL[20] ;

2: ;

3: R[56]=60 ;

4: ;

5: LBL[30] ;

6: R[R[56]]=0 ;

7: ;

8: WAIT DI[103]=ON+ ;

9: LINECOUNT[1] R[51] ;

10: LINECOUNT[2] R[52] ;

11: ;

12: R[R[56]]=R[51] ;

13: ;

14: R[51]=0 ;

15: R[58]=0 ;

16: ;

17: R[56]=R[56]+1 ;

18: IF R[56]>70,JMP LBL[20] ;

19: ;

20: JMP LBL[30] ;

21: ;

/POS

/END

//

**/PROG MAIN\_PICK**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 1;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: ;

2:L P[1:Above\_Object] 1000mm/sec CNT25 ;

3: ;

4:L P[2:Pick\_Positon] 750mm/sec FINE ;

5: ;

6: WAIT .30(sec) ;

7: CALL VACUUM\_ON ;

8: WAIT .50(sec) ;

9: ;

10:L P[1:Above\_Object] 1000mm/sec CNT25 ;

11: ;

/POS

P[1:"Above\_Object"]{

GP1:

UF : 0, UT : 1, CONFIG : 'N, , 0, 0',

X = -115.000 mm, Y = 32.500 mm, Z = 75.000 mm,

W = 180.000 deg, P = .009 deg, R = -89.980 deg

};

P[2:"Pick\_Positon"]{

GP1:

UF : 0, UT : 1, CONFIG : 'N, , 0, 0',

X = -110.000 mm, Y = 32.500 mm, Z = -12.000 mm,

W = 179.994 deg, P = .024 deg, R = -89.988 deg

};

/END

//

**/PROG VACUUM\_ON**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: ;

2: DO[101]=ON ;

3: DO[102]=OFF ;

4: ;

/POS

/END

//

**/PROG MAIN\_PLACE**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 2;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: ;

2: CALL RANDOM\_NUMBER ;

3: ;

4:L P[1] 1000mm/sec CNT25 Offset,PR[20] ;

5: ;

6:L P[2] 750mm/sec FINE Offset,PR[20] ;

7: ;

8: WAIT .25(sec) ;

9: CALL VACUUM\_OFF ;

10: WAIT .15(sec) ;

11: ;

12:L P[1] 1000mm/sec CNT25 Offset,PR[20] ;

13: ;

14: ;

/POS

P[1]{

GP1:

UF : 0, UT : 1, CONFIG : 'N, , 0, 0',

X = 260.000 mm, Y = -5.000 mm, Z = 45.000 mm,

W = 179.977 deg, P = .038 deg, R = 90.002 deg

};

P[2]{

GP1:

UF : 0, UT : 1, CONFIG : 'N, , 0, 0',

X = 260.000 mm, Y = -5.000 mm, Z = -12.000 mm,

W = 179.977 deg, P = .036 deg, R = 90.003 deg

};

/END

//

**/PROG RANDOM\_NUMBER**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: ;

2: R[53]=(3.8\*R[53]\*(1-R[53])) ;

3: ;

4: R[54]=R[53]\*300 ;

5: R[54]=R[54] DIV 1 ;

6: R[54]=R[54]-150 ;

7: PR[20,2]=R[54] ;

8: ;

9: R[53]=(3.8\*R[53]\*(1-R[53])) ;

10: ;

11: R[55]=R[53]\*100 ;

12: R[55]=R[55] DIV 1 ;

13: R[55]=R[55]-50 ;

14: PR[20,6]=R[55] ;

15: ;

/POS

/END

//

**/PROG VACUUM\_OFF**

LINE\_TRACK;

LINE\_TRACK\_SCHEDULE\_NUMBER : 0;

LINE\_TRACK\_BOUNDARY\_NUMBER : 0;

CONTINUE\_TRACK\_AT\_PROG\_END : TRUE;

/MN

1: ;

2: DO[101]=OFF ;

3: DO[102]=ON ;

4: ;

/POS

/END

//

**IO STATUS::**

|  |  |
| --- | --- |
| DIN[ 101] OFF Restart  DIN[ 102] OFF Start  DIN[ 103] OFF Photo cell Allen-B  DIN[ 104] OFF  DIN[ 105] OFF Fence open DR3 side  DIN[ 106] OFF  DIN[ 107] OFF  DIN[ 108] OFF  DIN[ 109] OFF  DIN[ 110] OFF  DIN[ 111] OFF Opticke\_barijere | DOUT[ 101] OFF Vacuum\_ON  DOUT[ 102] OFF Vacuum\_OFF  DOUT[ 103] OFF  DOUT[ 104] OFF  DOUT[ 105] OFF  DOUT[ 106] OFF Siemens Conveyor  DOUT[ 107] OFF  DOUT[ 108] OFF  DOUT[ 109] OFF  DOUT[ 110] OFF  DOUT[ 111] OFF |
| SI[ 1] OFF Fault reset  SI[ 2] ON Remote  SI[ 3] ON Hold  SI[ 4] OFF  SI[ 5] OFF  SI[ 6] OFF Cycle start  SI[ 7] OFF  SI[ 8] OFF CE/CR Select b0  SI[ 9] OFF CE/CR Select b1  SI[ 10] OFF  SI[ 11] OFF  SI[ 12] OFF  SI[ 13] OFF  SI[ 14] OFF  SI[ 15] OFF  SI[ 16] ON | SO[ 1] OFF Cycle start  SO[ 2] OFF Hold  SO[ 3] OFF Fault LED  SO[ 4] OFF Batt alarm  SO[ 5] OFF  SO[ 6] OFF  SO[ 7] OFF TP enabled  SO[ 8] OFF  SO[ 9] OFF  SO[ 10] OFF  SO[ 11] OFF  SO[ 12] OFF  SO[ 13] OFF  SO[ 14] OFF  SO[ 15] OFF |
| UI[ 1] ON \*IMSTP  UI[ 2] ON \*Hold  UI[ 3] ON \*SFSPD  UI[ 4] OFF Cycle stop  UI[ 5] OFF Fault reset  UI[ 6] OFF Start  UI[ 7] OFF Home  UI[ 8] ON Enable  UI[ 9] OFF RSR1/PNS1/STYLE1 |  |